Erlang中的映射組Map詳細介紹

% 不管你怎么排序，最終結(jié)果都是按鍵的字典順序排列的
#{ name => "wittyfox", age => 19 }.
% => #{age => 20,name => "wittyfox"}

% 也可以創(chuàng)建一個空的映射組
#{}.
% => #{}

% 現(xiàn)在的我
Me = #{ name => "wittyfox", age => 19 }.
% => #{age => 19,name => "wittyfox"}

% 過年啦，又長一歲了，變成嶄新的我啦
NewMe = Me#{ age => 20 }.
% => #{age => 20,name => "wittyfox"}

% 當(dāng)然也可以直接修改
#{ name => "wittyfox", age => 19 }#{ age => 20 }.
% => #{age => 20,name => "wittyfox"}

% 本來想更新 age，結(jié)果一不小心拼寫錯誤，創(chuàng)建了一個新的映射
Me#{ aeg => 20 }.
% => #{aeg => 20,age => 19,name => "wittyfox"}.

% 不存在 aeg 鍵，拋出 badarg 異常
Me#{ aeg := 20 }.
% ** exception error: bad argument ... blabla

% 只能更新已存在的映射
Me#{ age := 20 }.
% => #{age => 20,name => "wittyfox"}

#{ name := "wittyfox", age := 19 }.
% * 1: only association operators '=>' are allowed in map construction

% 部分匹配: 我們只想取出 age，所以我們只關(guān)心參數(shù)中有沒有 age 這個映射
#{ age := Age } = Me.
% => #{age => 19,name => "wittyfox"}

% Age.
% => 19

% 不合法的匹配
#{ age => Age } = Me.
% * 1: illegal pattern

 % 這里是創(chuàng)建映射組，只能使用 =>
 new() ->
     {ok, {?MODULE, #{name => "wittyfox", age => 19}}}.

 % 這里是匹配，只能使用 :=
 show({?MODULE, #{name := Name, age := Age}}) ->
     io:format("Name: ~p, Age: ~p~n", [Name, Age]).

% 創(chuàng)建映射組
maps:new().
% => #{}

% 返回所有鍵
maps:keys(Me).
% => [age,name]

% 判斷是否存在鍵
maps:is_key(age, Me).
% => true
maps:is_key(aeg, Me).
% => false

% 按鍵的順序返回所有值
maps:values(Me).
% =>[19,"wittyfox"]

% 映射數(shù)量
maps:size(Me).
% => 2

% 還可以使用 erlang:map_size/1
% 此函數(shù)可以用于 Guard，maps 模塊內(nèi)部也是使用此函數(shù)的
map_size(Me).
% => 2

% maps:get/2 在鍵不存在時會拋出異常
maps:get(age, Me).
% => 19

% maps:get/3 在鍵不存在時會返回第三個參數(shù)的值
maps:get(aeg, Me, 20).
% => 20

% 用于更新或創(chuàng)建映射，類似于 =>
% 所謂更新，只是返回更新后的新的映射組，原映射組并不會改變
maps:put(gender, male, Me).
% => #{age => 19,gender => male,name => "wittyfox"}

% 用于更新映射，類似于 :=，鍵不存在時會拋出 badarg 異常
maps:update(age, 20, Me).
% => #{age => 20,name => "wittyfox"}

% 刪除一個映射，鍵不存在時相當(dāng)于什么都沒做，不會拋出異常
maps:remove(age, Me).
% => #{name => "wittyfox"}

% 查找鍵的值，鍵不存在時返回 error
maps:find(age, Me).
% => {ok, 19}

maps:find(aeg, Me).
% => error

% 歸并兩個映射組，注意第二個參數(shù)是創(chuàng)建新的映射組，所以只能用 =>
maps:merge(Me, #{ age => 10 }).  
% => #{age => 10,name => "wittyfox"}

% 相當(dāng)于
Me#{ age => 10 }.

% 返回映射元組對的列表
maps:to_list(Me).
% => [{age,19},{name,"wittyfox"}]

% 從列表構(gòu)建映射組
maps:from_list([]).
% => #{}

maps:from_list([{name, "wittyfox"}, {age, 19}]).
% => #{age => 19,name => "wittyfox"}

% 對映射組的每對映射執(zhí)行操作
% X, Y 分別為一對映射的鍵和值
maps:map(fun (X, Y) -> io:format("~p => ~p~n", [X, Y]) end, Me). 
% age => 19                                             % 輸出
% name => "wittyfox"                                    % 輸出
% => #{age => ok,name => ok}                            % 返回值

% X, Y 分別為一對映射的鍵和值，V 為上一次迭代的結(jié)果，0 為迭代的初始值
% 這里簡單的用于每次迭代時值加 1，結(jié)果就是映射組的映射數(shù)量
maps:fold(fun (X, Y, V) -> V + 1 end, 0, Me).
% => 2

maps:with([], Me).
% => #{}

maps:with([age], Me).
% => #{age => 19}

% 鍵可以不存在
maps:with([aeg], Me).
% => #{}

maps:without([], Me).
% => #{age => 19,name => "wittyfox"}

maps:without([age], Me).
% => #{name => "wittyfox"}

% 鍵也可以不存在
maps:without([age, neme], Me).
% => #{name => "wittyfox"}